Bilgisayarınızı veya diğer cihazlarınızı uzaktan kontrol etmek için AnyDesk kullanıyorsanız ve AnyDesk Kimliğinizi sıfırlamak istiyorsanız, aşağıyı okumaya devam edin. Anydesk reklam nasıl kapatılır, AnyDesk Uzak Masaüstü Kimlik Adresini Nasıl Sıfırlarım, Anydesk reklam nasıl kapatılır
AnyDesk ID, AnyDesk uygulamasını çalıştırırken her bilgisayara atanan ve AnyDesk ağında tanımlanmasını sağlayan benzersiz bir numaradır. Herhangi bir nedenle Windows bilgisayarda AnyDesk ID’yi değiştirmek isterseniz, aşağıdaki talimatları okuyun.
* Not: AnyDesk Free Sürümünde kimliği değiştirebileceğinizi ancak bir takma adı değiştiremeyeceğinizi veya atayamayacağınızı unutmayın. Bilgisayarlara ad atayabilmek için programın kurumsal veya profesyonel bir sürümünü satın almanız gerekir.
Aşağıda ki kodu Cmd de yönetici olarak çalışıtırınız, Anydesk açık ise kapatıp tekrar açınız, id adresi sürekli değişecektir.
@echo off & setlocal enableextensions
title Reset AnyDesk
reg query HKEY_USERS\S-1-5-19 >NUL || (echo Please Run as administrator.& pause >NUL&exit)
chcp 437
call :stop_any
del /f "%ALLUSERSPROFILE%\AnyDesk\service.conf"
del /f "%APPDATA%\AnyDesk\service.conf"
copy /y "%APPDATA%\AnyDesk\user.conf" "%temp%\"
rd /s /q "%temp%\thumbnails" 2>NUL
xcopy /c /e /h /r /y /i /k "%APPDATA%\AnyDesk\thumbnails" "%temp%\thumbnails"
del /f /a /q "%ALLUSERSPROFILE%\AnyDesk\*"
del /f /a /q "%APPDATA%\AnyDesk\*"
call :start_any
:lic
type "%ALLUSERSPROFILE%\AnyDesk\system.conf" | find "ad.anynet.id=" || goto lic
call :stop_any
move /y "%temp%\user.conf" "%APPDATA%\AnyDesk\user.conf"
xcopy /c /e /h /r /y /i /k "%temp%\thumbnails" "%APPDATA%\AnyDesk\thumbnails"
rd /s /q "%temp%\thumbnails"
call :start_any
echo *********
echo Completed.
echo(
goto :eof
:start_any
sc start AnyDesk
sc start AnyDesk
if %errorlevel% neq 1056 goto start_any
set AnyDesk1=%SystemDrive%\Program Files (x86)\AnyDesk\AnyDesk.exe
set AnyDesk2=%SystemDrive%\Program Files\AnyDesk\AnyDesk.exe
if exist "%AnyDesk1%" start "" "%AnyDesk1%"
if exist "%AnyDesk2%" start "" "%AnyDesk2%"
exit /b
:stop_any
sc stop AnyDesk
sc stop AnyDesk
if %errorlevel% neq 1062 goto stop_any
taskkill /f /im "AnyDesk.exe"
exit /b
